Использование#

pipeline {
    agent {
        // Имя Jenkins агента с сетевым доступом к {argo-url}
        label '<your-agent>'
    }

    parameters {
        string(name: "CODE", description: "Код продукта")
        string(name: "VERSION", defaultValue: "", description: "Версия продукта")
        string(name: "GROUP_ID", defaultValue: "", description: "Параметр 'groupId' (если не указан, то используется 'groupId' из doc-config.ini)")
    }

    environment {
        // Базовый URL к Argo Workflows
        ARGO_BASE_URL = "https://argo-url/argowf"

        // Название Jenkins credentials типа Secret text, в котором находится строка с token (без 'Bearer')
        ARGO_CREDENTIALS = "<your-credentials>"

        // Пространство имен должно быть "getdocs-prod"
        NAMESPACE = "getdocs-prod"
    }

    stages {
        stage('Отправка запроса в GetDocs') {
            steps {
                script {
                    final String submitData = """{
                        "namespace": "$NAMESPACE",
                        "resourceKind": "WorkflowTemplate",
                        "resourceName": "load-to-nexus",
                        "submitOptions": {
                            "parameters": [
                                "code=$CODE",
                                "version=$VERSION",
                                "group_id=$GROUP_ID"
                            ],
                            "labels": "submit-from-api=true"
                        }
                    }"""

                    echo "Submitting workflow with data: $submitData"

                    withCredentials([string(credentialsId: "$ARGO_CREDENTIALS", variable: 'ARGO_TOKEN')]) {
                        // Запрос на создание workflow
                        def submitResponse = httpRequest httpMode: 'POST',
                            url: "$ARGO_BASE_URL/api/v1/workflows/$NAMESPACE/submit",
                            requestBody: submitData,
                            customHeaders: [[name: 'Authorization', value: 'Bearer ' + ARGO_TOKEN]],
                            contentType: 'APPLICATION_JSON',
                            validResponseCodes: '200',
                            ignoreSslErrors: true;

                        final Object submitResponseJson = new groovy.json.JsonSlurperClassic().parseText(submitResponse.content);
                        final String workflowName = submitResponseJson.metadata.name;

                        final String workflowUrl = "$ARGO_BASE_URL/workflows/$NAMESPACE/$workflowName"

                        sleep(10)

                        // Периодический запрос на получение результата workflow
                        while(true) {
                            def workflowResponse = httpRequest url: "$ARGO_BASE_URL/api/v1/workflows/$NAMESPACE/$workflowName",
                                customHeaders: [[name: 'Authorization', value: 'Bearer ' + ARGO_TOKEN]],
                                contentType: 'APPLICATION_JSON',
                                validResponseCodes: '200',
                                ignoreSslErrors: true;

                            final Object workflowResponseJson = new groovy.json.JsonSlurperClassic().parseText(workflowResponse.content);
                            final String workflowStatus = workflowResponseJson.status.phase;

                            if (workflowStatus in [null, "Pending", "Running"]) {
                                echo "Workflow status of '$workflowName' is '$workflowStatus', retrying in 10 seconds..."
                                sleep(10)
                                continue
                            }

                            if (workflowStatus in ["Failed", "Error"]) {
                                echo "Workflow '$workflowName' has '$workflowStatus'. See logs at $workflowUrl"
                                break
                            }

                            if (workflowStatus == "Succeeded") {
                                echo "Workflow '$workflowName' has succeeded."

                                final Object workflowOutputParameters = workflowResponseJson.status.nodes."$workflowName".outputs.parameters;

                                final String archiveLink = workflowOutputParameters.find {it.name == "link" }.value;

                                final String nonApprovedComponents = workflowOutputParameters.find {it.name == "non_approved" }.value;

                                echo "Archive link: $archiveLink"
                                echo "Non approved components: $nonApprovedComponents"
                                echo "Workflow URL: $workflowUrl"
                                break;
                            }

                            echo "Workflow status of '$workflowName' is '$workflowStatus', aborting."
                            break
                        }
                    }
                }
            }
        }
    }
}